MODE C = COMPLEX, R = REAL;
PROC assert = (INT j, BOOL u)VOID: (u|SKIP|print(("Bye", j, newline)); hell);
PROC sz = (C x)R: (REAL r = ABS RE x, i = ABS IM x; (r<i|i|r));
# Snitching from formula 1 here:
http://en.wikipedia.org/wiki/Invertible_matrix #
OP * = ([]C a, []C b)C: (INT n = UPB a; assert(2, n = UPB b);
  C s := 0; FOR j TO n DO s +:= a[j]*b[j] OD; s);
OP * = ([,]C b, [,]C c)[,]C: (INT m = 1 UPB b, n = 2 UPB b, o = 2 UPB c;
  assert(4, n=1 UPB c);
  [m,o]C a; FOR j TO m DO FOR k TO o DO a[j,k] := b[j,]*c[,k] OD OD; a);
OP - = ([,]C d, [,]C v)[,]C: (INT m = 1 UPB d, n = 2 UPB d;
  assert(5, m = 1 UPB v & n = 2 UPB v); [m,n]C a;
  FOR j TO m DO FOR k TO n DO a[j,k] := d[j,k] - v[j,k] OD OD; a);
OP +:= = (REF[,]C a, [,]C b)VOID: (INT m = 1 UPB a, n = 2 UPB a;
  assert(6, m = 1 UPB b & n = 2 UPB b);
  FOR j TO m DO FOR k TO n DO a[j,k] +:= b[j,k] OD OD);
OP - = ([,]C a)[,]C: (INT m = 1 UPB a, n = 2 UPB a;
  [m,n]C s; FOR j TO m DO FOR k TO n DO s[j,k] := -a[j,k] OD OD; s);

PROC inv = ([,]C mp)[,]C : (INT n = 1 UPB mp; assert(1, n = 2 UPB mp);
  (n=1 | 1/mp[1,1] |
  [n,n]C m; INT n1 = n OVER 2; INT n2 = n1+1;
    m[:n1,:n1] := inv(mp[:n1,:n1]);
    [,]C aib = m[:n1,:n1]*mp[:n1,n2:], cai = mp[n2:,:n1]*m[:n1,:n1];
    m[n2:,n2:] := inv(mp[n2:,n2:] - mp[n2:,:n1]*aib);
    m[:n1,n2:] := -aib*m[n2:,n2:];
    m[n2:,:n1] := -m[n2:,n2:]*cai;
    m[:n1,:n1] +:= aib*m[n2:,n2:]*cai;
    m));

PROC tst = ([,]C m)VOID: (INT n = 1 UPB m; [,]C i = inv(m); [,]C p = i*m;
  FOR j TO n DO FOR k TO n DO assert(-1, (sz (p[j,k] - (j=k|1|0)) < 1.e-11)) OD OD);

PROC tr = (INT n)VOID: ([n,n]C m; FOR j TO n DO FOR k TO n DO
   m[j,k] := (4*nextrandom-2) I (4*nextrandom-2) OD OD; tst(m));

FOR j TO 8 DO
(j|tst(((2, 4, 5), (3, 2, 5), (5, 7, 4))),
tst(((10, 2, 3), (2, 11, 4), (3, 2, 14))),
tst(((2, 3), (4, 5))),
tst(((1, 2), (0, 1))),
tst(((1, 0, 0), (0, 1, 0), (1.1, 0, 1))),
tr(7), tr(18), tr(60)) OD

 EXIT hell: print("The Bitter End")